#include <Arduino_FreeRTOS.h>
// Добавление функций FreeRTOS для семафоров (или флагов, Flags):
#include <semphr.h>

// Декларирование хендла мьютексного семафора, который будет
// использоваться для обслуживания порта Serial.
// Хендл семафора нужен, чтобы гарантировать, что только одна
// задача в любой момент времени получила доступ к Serial.
SemaphoreHandle_t xSerialSemaphore;

// Определение двух задач (Task) для цифрового (DigitalRead)
// и аналогового (AnalogRead) ввода:
void TaskDigitalRead( void *pvParameters );
void TaskAnalogRead( void *pvParameters );

// Функция setup запустится только один раз, когда Вы нажмете
// кнопку сброса (reset), или когда на плату будет подано питание:
void setup() {
   // Инициализация последовательного обмена на скорости 9600 бит/сек:
  Serial.begin(9600);

   // Семафоры полезны для остановки задачи, когда она должна
   // быть поставлена на паузу для ожидания из-за необходимости
   // доступа к общему ресурсу. В нашем случае это порт Serial.
   // Семафоры должны использоваться только когда работает
   // планировщик, но здесь мы можем их настроить.
   // Проверка, что семафор уже не создан:
   if ( xSerialSemaphore == NULL )
   {
      // Создание мьютексного семафора, который мы будем использовать
      // для обслуживания доступа к порту Serial:
      xSerialSemaphore = xSemaphoreCreateMutex();
      if ( ( xSerialSemaphore ) != NULL )
      {
         // Если семафор создан, то делаем его доступным (Give)
         // для использования при доступе к порту Serial:
         xSemaphoreGive( ( xSerialSemaphore ) );
      }
   }

   // Теперь настроим 2 задачи, чтобы они работали независимо.
   xTaskCreate(
      TaskDigitalRead
      ,  (const portCHAR *)"DigitalRead"  // Это просто любое читаемое имя
      ,  128   // этот размер стека задачи может быть проверен и подстроен
               // с помощью чтения значения Stack Highwater
      ,  NULL
      ,  2     // приоритет (1 самый высший, 4 самый низший) задачи
      ,  NULL );

   xTaskCreate(
      TaskAnalogRead
      ,  (const portCHAR *) "AnalogRead"
      ,  128   // размер стека задачи
      ,  NULL
      ,  1     // приоритет задачи
      ,  NULL );

   // Теперь автоматически запустится планировщик задач (Task scheduler),
   // который будет управлять их запуском.
}

void loop()
{
   // Здесь пустота. Все действия выполняются в теле задач (Tasks).
}

/*--------------------------------------------------*/
/*----------- Tasks (определения задач) ------------*/
/*--------------------------------------------------*/

void TaskDigitalRead( void *pvParameters __attribute__((unused)) )
{
   /*
      DigitalReadSerial
      Эта задача читает цифровой вход 2, и печатает результат
      в консоль порта Serial.
   */

   // К цифровому выводу 2 подключена кнопка. Дадим ему имя:
   uint8_t pushButton = 2;

   // Настроим этот вывод как вход:
   pinMode(pushButton, INPUT);

   for (;;)    // Бесконечный цикл задачи.
   {
      // Чтение уровня на цифровом входе:
      int buttonState = digitalRead(pushButton);

      // Посмотрим, можем ли мы "взять" (Take) семафор.
      // Если семафор недоступен, ждем 5 тиков планировщика,
      // после чего снова проверим семафор.
      if ( xSemaphoreTake( xSerialSemaphore, ( TickType_t ) 5 ) == pdTRUE )
      {
         // Здесь мы можем "взять" семафор, и таким образом получить
         // исключительный доступ к общему ресурсу Serial.
         // Исключительный доступ к порту Serial нужен для того, чтобы
         // наш выводимый текст не было испорчен другими задачами.
         // Напечатаем состояние кнопки:
         Serial.println(buttonState);
         // Теперь освободим семафор (или "отдадим" его, Give), чтобы
         // порт Serial был доступен для любых задач.
         xSemaphoreGive( xSerialSemaphore );
      }
      // Задержка в 1 тик (15 мс) между чтениями, для стабильности:
      vTaskDelay(1);
   }
}

void TaskAnalogRead( void *pvParameters __attribute__((unused)) )
{
   for (;;)
   {
      // Прочитаем значение аналогового входа 0:
      int sensorValue = analogRead(A0);

      // Посмотрим, можем ли мы "взять" (Take) семафор.
      // Если семафор недоступен, ждем 5 тиков планировщика,
      // после чего снова проверим семафор.
      if ( xSemaphoreTake( xSerialSemaphore, ( TickType_t ) 5 ) == pdTRUE )
      {
         // Здесь мы можем "взять" семафор, и таким образом получить
         // исключительный доступ к общему ресурсу Serial.
         // Исключительный доступ к порту Serial нужен для того, чтобы
         // наш выводимый текст не было испорчен другими задачами.
         // Напечатаем прочитанное значение:
         Serial.println(sensorValue);
         // Теперь освободим семафор (или "отдадим" его, Give), чтобы
         // порт Serial был доступен для любых задач.
         xSemaphoreGive( xSerialSemaphore );
      }
      // Задержка в 1 тик (15 мс) между чтениями, для стабильности:
      vTaskDelay(1);
   }
}